spielgeräte bau

Details: Kategorie: spielgeräte; Erstellt: 31. März 2026; Zugriffe: 27

Der Heiße Draht ist ein Geduldsspiel und der absolute Klassiker unter den Geschicklichkeitsspielen. Beim heißen Draht kommt es auf eine ruhige Hand an, denn das Ziel ist es, eine Metallöse an einem gebogenen Draht oder Rohr entlangzuführen, ohne diesen zu berühren.

Sobald sich die Öse und der Draht berühren, schließt sich ein Stromkreis. Der Arduino registriert diesen Kontakt sofort und reagiert – je nach Ausführung – mit einem Summen, dem Aufleuchten von LEDs oder einer Anzeige auf einem Monitor. Es ist das perfekte Projekt, um die Grundlagen von digitalen Eingängen und der Interaktion mit verschiedenen Ausgabemedien zu verstehen.

Auf meiner Website Seite habe ich im Laufe der Zeit extrem viele verschiedene Ideen, Skizzen und Experimente zum „Heißen Draht“ veröffentlicht. Da dort mittlerweile so viele Ansätze durcheinandergewürfelt sind, wurde es Zeit für ein wenig Ordnung. So habe ich die fünf am meisten nachgebauten und beliebtesten Versionen herausgepickt, um sie hier kompakt und übersichtlich für dich zusammenzufassen.

Variante	Technik	Feedback	Schwierigkeit
1. Puristisch	Batterie & LED	Sofort-Signal	Sehr einfach
2. Zeit-Logik	NE555 Timer	1 Sek. Signal	Einfach (Löten)
3. Arduino Basic	Mikrocontroller	3 LEDs & Sound	Mittel
4. Visual Artist	Processing (PC)	Grafische Anzeige	Fortgeschritten
5. Arccade Box	4 Zoll TFT	Standalone-Monitor	Profi

1. Die puristische Variante (Batterie & LED)

Diese Variante ist im Grunde nichts anderes als ein riesiger, offener Schalter. Sie ist das perfekte Praxisbeispiel für einen ganz klassischen Stromkreis, wie man ihn in den ersten Stunden des Physikunterrichts lernt. Anstelle eines herkömmlichen Wippschalters übernehmen hier die Metallöse und der gebogene Draht die Aufgabe, den Stromfluss aktiv zu steuern. Erst wenn sich diese beiden metallischen Komponenten berühren, wird die physikalische Lücke im System geschlossen, sodass die elektrische Energie der Batterie ungehindert zur LED und zum Summer fließen kann.

Bauteile
- 9 Volt Batterie mit Batterieclip
- Aktiver Summer
- Schalter
- 470 Ohm Wiederstand
- LED

2. Die Logik-Variante mit (NE555 Timer) IC

Damit das Fehlersignal nicht nur für den Bruchteil einer Sekunde ertönt, du aber nicht programmieren willst, kannst du einen Timer-Baustein NE555 verwenden. In dieser speziellen Beschaltung arbeitet er als sogenannte monostabile Kippstufe. Das bedeutet: Ein kurzer Startimpuls löst eine Aktion für eine fest definierte Zeitspanne aus. Einfach gesagt: Der kurze Wackler an der Öse kippt den sprichwörtlichen Eimer Wasser um, und die LED leuchtet genau so lange, bis der Eimer (Kondensator) wieder vollgetropft ist.

Bauteile:
- NE555 oder LM555.
- 3x Wiederstand gelb, lila, gelb = 4,7 K.Ohm.
- 1x Wiederstand gelb, lila, baun = 470 Ohm.
- Elektrolyt Kondensator 100 (–)220 uF, je kleiner desto kürzer ist die LED bei einem Fehler eingeschaltet.
- Keramik Kondensator (zwischen 5 und GND) 100nf.
- LED und Summer (parallel zur LED möglich)

3. Die smarte Variante (Arduino Uno)

Der Arduino übernimmt die Auswertung und zählt sogar deine Fehler mit. Über die Variable "const int numLeds = 3;" im Code kannst du einfach einstellen wie viele LED du angeschlossen hast. Sind alle Fehler "voll" dann ist das Spiel zu Ende.

Ablauf:
- Über den Arduino wird das Spiel gestartet, gestoppt und resettet. Bei jeden Fehler leichtet eine LED "weiter" auf und der Summer ertönt für eine Sekunde.
Verdrahtung:
- Start-Taster: Pin A0 (gegen GND)
- Stop-Taster (Ziel): Pin A1 (gegen GND)
- Heißer Draht (Öse): Pin A2 (gegen GND)
- Summer: Pin D13 (optional)
- LEDs: Beginnend bei D2 aufwärts (je nach eingestellter Anzahl)
Anzeige von 11 Fehlern möglich.
- Änderung über "const int numLeds = 3;"

Vorbereitung (Reset): Bevor es losgeht, drückst du den Reset-Taster (A1). Alle LEDs blinken kurz auf und erlöschen dann. Das System ist nun „frisch“ und bereit.
Spiel starten (A0): Berühre mit deiner Öse kurz die Start-Platte (A0). Ein kurzer Bestätigungston ertönt. Das Spiel ist jetzt „scharf“ geschaltet und die Fehler-Überwachung läuft.
Der Draht-Kontakt (A2): Konzentrier dich! Sobald du den Draht (A2) mit der Öse berührst, ertönt der Summer und die erste Fehler-LED geht an. Bei jedem weiteren Wackler schaltet der Arduino eine zusätzliche LED ein – die Fehler summieren sich also als Balken auf.
Ziel erreicht (A0): Hast du das Ende des Drahtes erreicht? Berühre die Ziel-Platte (A0). Eine Sieg-Melodie spielt ab. Der Draht ist nun sofort deaktiviert, sodass du beim Wegnehmen der Öse keine versehentlichen Fehler mehr auslöst. Deine Fehler-LEDs bleiben zur Auswertung einfach stehen.
Game Over (Limit erreicht): Solltest du zu viele Fehler machen und alle LEDs leuchten, ist das Spiel automatisch beendet. Die LEDs blinken wild und bleiben danach alle dauerhaft an.
Die Sperre: Nach einem „Game Over“ oder einem Sieg ist die Start-Platte (A0) gesperrt. Du kannst kein neues Spiel starten, solange die LEDs noch leuchten. Drücke erst wieder Reset (A1), um die Anzeige zu leeren und das nächste Duell zu beginnen.

Der Arduino Code für das einfache heiße Draht Spiel

// www.kreativekiste.de 
// 01.04.2026 
// Version 1.5

const int numLeds = 5;         // Anzahl der Fehler-LEDs (1 bis 11)
const int firstLedPin = 2;     // Start-Pin für LEDs
const int startStopPin = A0;   // Start- und Stop-Kontakt
const int resetPin = A1;       // Reset-Taster
const int drahtPin = A2;       // Die Öse / Der Draht
const int buzzerPin = 13;      // Summer

int fehlerZaehler = 0;
bool spielAktiv = false;
bool kontaktAktiv = false;
bool zielErreicht = false;

void setup() {
  pinMode(startStopPin, INPUT_PULLUP);
  pinMode(resetPin, INPUT_PULLUP);
  pinMode(drahtPin, INPUT_PULLUP);
  pinMode(buzzerPin, OUTPUT);

  for (int i = 0; i < numLeds; i++) {
    pinMode(firstLedPin + i, OUTPUT);
    digitalWrite(firstLedPin + i, LOW);
  }
}

void loop() {
  // RESET (A1): Alles auf Null
  if (digitalRead(resetPin) == LOW) {
    resetAnimation();
    resetData();
    delay(200); // Entprellen
  }

  // START / STOP (A0)
  if (digitalRead(startStopPin) == LOW) {
    delay(250); // Entprellen
    if (!spielAktiv && !zielErreicht) {
      // SPIEL STARTEN
      spielAktiv = true;
      fehlerZaehler = 0;
      kontaktAktiv = false; // Zur Sicherheit hier auch nochmal
      allLedsOff();
      tone(buzzerPin, 1000, 200);
    } 
    else if (spielAktiv) {
      // SPIEL STOPPEN (Ziel erreicht)
      spielAktiv = false;
      zielErreicht = true;
      goalReachedSound(); 
    }
  }

  // FEHLER-ERFASSUNG (A2)
  if (spielAktiv) {
    if (digitalRead(drahtPin) == LOW && !kontaktAktiv) {
      kontaktAktiv = true;
      fehlerZaehler++;
      
      digitalWrite(buzzerPin, HIGH);
      
      // LED bei Fehler einschalten
      if (fehlerZaehler <= numLeds) {
        digitalWrite(firstLedPin + fehlerZaehler - 1, HIGH);
      }
      
      delay(200);
      digitalWrite(buzzerPin, LOW);

      // GAME OVER
      if (fehlerZaehler >= numLeds) {
        spielAktiv = false;
        gameOver();
      }
    }

    // Kontakt-Flag zurücksetzen, wenn Draht wieder frei
    if (digitalRead(drahtPin) == HIGH) {
      kontaktAktiv = false;
    }
  }
}

void resetData() {
  fehlerZaehler = 0;
  spielAktiv = false;
  zielErreicht = false;
  kontaktAktiv = false; // Das war der fehlende Baustein!
  allLedsOff();
}

void allLedsOff() {
  for (int i = 0; i < numLeds; i++) {
    digitalWrite(firstLedPin + i, LOW);
  }
}

void resetAnimation() {
  for (int i = 0; i < 2; i++) {
    for (int j = 0; j < numLeds; j++) digitalWrite(firstLedPin + j, HIGH);
    delay(150);
    for (int j = 0; j < numLeds; j++) digitalWrite(firstLedPin + j, LOW);
    delay(150);
  }
}

void gameOver() {
  // Erst blinken
  for (int i = 0; i < 4; i++) {
    for (int j = 0; j < numLeds; j++) digitalWrite(firstLedPin + j, HIGH);
    tone(buzzerPin, 150);
    delay(200);
    for (int j = 0; j < numLeds; j++) digitalWrite(firstLedPin + j, LOW);
    noTone(buzzerPin);
    delay(200);
  }
  // Dann alle LEDs anlassen als Signal für "Reset nötig"
  for (int j = 0; j < numLeds; j++) {
    digitalWrite(firstLedPin + j, HIGH);
  }
  zielErreicht = true; 
}

void goalReachedSound() {
  tone(buzzerPin, 1200, 150);
  delay(200);
  tone(buzzerPin, 1500, 150);
  delay(200);
  tone(buzzerPin, 1800, 300);
}

4: Die visuelle Show, riesige Anzeige für den heißen Draht, bei minimalem Aufwand

Wenn du keine Lust hast, dutzende LEDs zu verlöten oder dich mit Displays herumzuärgern, dann ist diese Variante genau dein Ding. Hier nutzt du, was wahrscheinlich sowieso schon auf deinem Schreibtisch stehen hast: deinen Computer oder Laptop.

Der Clou an dieser Schaltung ist die maximale Wirkung bei minimaler Hardware. Da du die komplette Anzeige auf den PC-Monitor auslagerst, fällt das nervige Verdrahten fast komplett weg. Du bekommst eine riesige, farbige und professionelle Anzeige quasi „kostenlos“ dazu, weil dein Monitor die ganze Arbeit übernimmt.

Das Zusammenspiel: Arduino IDE und Processing

In der Arduino IDE überträgst du den Code, der lediglich darauf wartet, dass die Öse den Draht berührt. Sobald das passiert, sendet der Arduino über das USB-Kabel einen Befehl an den PC. Das passiert über die sogenannte serielle Schnittstelle. Der Arduino sagt quasi: „Hey, da war gerade ein Kontakt!“
Processing ist eine Software, die der Arduino IDE optisch sehr ähnlich sieht, aber darauf spezialisiert ist, Grafiken auf dem PC-Bildschirm zu erzeugen. Das Processing-Programm „lauscht“ am USB-Port. Sobald das Signal vom Arduino eintrifft, reagiert die Software sofort – zum Beispiel, indem sie den Bildschirm rot färbt, einen Fehlerzähler hochzählt oder ein lautes Geräusch über die PC-Lautsprecher abspielt.
Ein großer Vorteil von Processing ist die sogenannte Export-Funktion. Du musst nicht jedes Mal die Processing-Entwicklungsumgebung öffnen, um das Spiel zu starten.
- In Processing gibt es den Menüpunkt „Export Application“.
- Dadurch erstellt die Software einen fertigen Ordner
- Darin findest du eine echte .exe-Datei (unter Windows).
- Du musst nur den Com Port unter "String portName = "COM4";" einstellen.
- Im Code steht der Bildschirm auf einer festen größe, diese kannst du ändern auf Vollbild stellen
  - size(1024, 768); // ändere hier eine feste Größe
  - fullScreen(); //ändere hier auf Vollbild
- Alle freien Pins im Schaltplan mit GND verbinden!!!

Der Arduino Code für das Spiel mit Monitor Anzeige

// www.kreativekiste.de 
// 2026-03-31 
// Version 3.6

#include <Arduino.h>
#include <EEPROM.h>

const int DRAHT_PIN = 2;   
const int BUTTON_PIN = 3;  
const int BUZZER_PIN = 4;  
const int LED_PIN = 5;     

struct Record {
  char name[4];
  float gesamtZeit;
};

struct Config {
  char magic[5];
  int strafSekunden;
  char letztesDatum[11];
  Record top3AllTime[3];
  Record top3Today[3];
};

Config settings;

int zustand = 1; 
unsigned long startMillis = 0;
unsigned long laufzeit = 0;

volatile int fehler = 0;
volatile bool kontaktErkannt = false;
volatile unsigned long letzterInterruptMillis = 0;

unsigned long letzterFehlerMillis = 0; 
unsigned long alarmStartMillis = 0;
bool alarmAktiv = false;

int lastButtonState = HIGH;
int currentButtonState = HIGH;
unsigned long lastDebounceTime = 0;

void fehlerISR() {
  if (zustand == 2) {
    unsigned long currentMillis = millis();
    if (currentMillis - letzterInterruptMillis > 50) { 
      kontaktErkannt = true;
      letzterInterruptMillis = currentMillis;
    }
  }
}

void resetTodayRecords() {
  for(int i = 0; i < 3; i++) {
    strncpy(settings.top3Today[i].name, "---", 4);
    settings.top3Today[i].gesamtZeit = 999.9;
  }
}

void resetAllRecords(int neueStrafzeit) {
  strncpy(settings.magic, "HD02", 5); 
  settings.strafSekunden = neueStrafzeit;
  resetTodayRecords();
  for(int i = 0; i < 3; i++) {
    strncpy(settings.top3AllTime[i].name, "---", 4);
    settings.top3AllTime[i].gesamtZeit = 999.9;
  }
  EEPROM.put(0, settings);
}

void setup() {
  Serial.begin(115200);
  pinMode(DRAHT_PIN, INPUT_PULLUP);
  pinMode(BUTTON_PIN, INPUT_PULLUP); 
  pinMode(BUZZER_PIN, OUTPUT);
  pinMode(LED_PIN, OUTPUT);
  
  attachInterrupt(digitalPinToInterrupt(DRAHT_PIN), fehlerISR, FALLING);
  
  EEPROM.get(0, settings);
  if (strcmp(settings.magic, "HD02") != 0) {
    resetAllRecords(3); 
  }
}

void sendScoresToPC() {
  Serial.print("SCORES;");
  for(int i=0; i<3; i++) { Serial.print(settings.top3AllTime[i].name); Serial.print(";"); Serial.print(settings.top3AllTime[i].gesamtZeit); Serial.print(";"); }
  for(int i=0; i<3; i++) { Serial.print(settings.top3Today[i].name); Serial.print(";"); Serial.print(settings.top3Today[i].gesamtZeit); Serial.print(";"); }
  Serial.println();
}

void stopAlarm() {
  digitalWrite(BUZZER_PIN, LOW);
  digitalWrite(LED_PIN, LOW);
  alarmAktiv = false;
}

void startAlarm(unsigned long currentMillis) {
  digitalWrite(BUZZER_PIN, HIGH);
  digitalWrite(LED_PIN, HIGH);
  alarmStartMillis = currentMillis;
  alarmAktiv = true;
}

void processCommand(String c) {
  c.trim(); 
  unsigned long currentMillis = millis();
  
  if (c == "START") { 
    zustand = 2; 
    startMillis = millis(); 
    fehler = 0; 
    letzterFehlerMillis = 0; 
    kontaktErkannt = false; 
    stopAlarm(); 
  }
  else if (c == "STOP") { 
    if (zustand == 2 && currentMillis - startMillis >= 500) { 
      zustand = 3; 
      stopAlarm(); 
    }
  }
  else if (c == "RESET") { zustand = 1; laufzeit = 0; fehler = 0; stopAlarm(); }
  else if (c == "GET_SCORES") { sendScoresToPC(); }
  else if (c.startsWith("NEWSTR:")) { 
    int s = c.substring(7).toInt();
    resetAllRecords(s);
    sendScoresToPC();
  }
  else if (c.startsWith("DATE:")) { 
    String d = c.substring(5);
    if (d != String(settings.letztesDatum)) {
      resetTodayRecords();
      d.toCharArray(settings.letztesDatum, 11);
      EEPROM.put(0, settings);
    }
  }
  else if (c.startsWith("SAVESCORE:")) {
    int p1 = c.indexOf(':', 10);
    String typ = c.substring(10, p1);
    int p2 = c.indexOf(':', p1 + 1);
    int index = c.substring(p1 + 1, p2).toInt();
    int p3 = c.indexOf(':', p2 + 1);
    String nStr = c.substring(p2 + 1, p3);
    float z = c.substring(p3 + 1).toFloat();

    if (typ == "ALL") {
      for(int i = 2; i > index; i--) { settings.top3AllTime[i] = settings.top3AllTime[i-1]; }
      nStr.toCharArray(settings.top3AllTime[index].name, 4);
      settings.top3AllTime[index].gesamtZeit = z;
    } else if (typ == "TODAY") {
      for(int i = 2; i > index; i--) { settings.top3Today[i] = settings.top3Today[i-1]; }
      nStr.toCharArray(settings.top3Today[index].name, 4);
      settings.top3Today[index].gesamtZeit = z;
    }
    EEPROM.put(0, settings);
    sendScoresToPC(); 
  }
}

void loop() {
  if (Serial.available() > 0) {
    String cmd = Serial.readStringUntil('\n');
    processCommand(cmd);
  }

  unsigned long currentMillis = millis();

  if (zustand == 2) {
    laufzeit = currentMillis - startMillis;
    bool aktuellKontakt = (digitalRead(DRAHT_PIN) == LOW);

    if (laufzeit >= 1000) {
      if (kontaktErkannt || aktuellKontakt) {
        if (currentMillis - letzterFehlerMillis >= 700) {
          fehler++;
          letzterFehlerMillis = currentMillis; 
          startAlarm(currentMillis);
        }
        kontaktErkannt = false; 
      }
    } else {
      kontaktErkannt = false;
    }
  }

  if (alarmAktiv && (currentMillis - alarmStartMillis >= 1000)) {
    stopAlarm();
  }

  int reading = digitalRead(BUTTON_PIN);
  if (reading != lastButtonState) {
    lastDebounceTime = currentMillis;
  }
  if ((currentMillis - lastDebounceTime) > 50) {
    if (reading != currentButtonState) {
      currentButtonState = reading;
    }
  }
  lastButtonState = reading;

  int btnStatus = (currentButtonState == LOW) ? 1 : 0;

  Serial.print(laufzeit); Serial.print(";");
  Serial.print(fehler); Serial.print(";");
  Serial.print(zustand); Serial.print(";");
  Serial.print(settings.strafSekunden); Serial.print(";");
  Serial.println(btnStatus);
  
  delay(15); 
}

Der Processing Code für das Spiel mit Monitor Anzeige

// www.kreativekiste.de 
// 2026-04-01 
// Version 4.5

import processing.serial.*;
import controlP5.*;

Serial myPort;
ControlP5 cp5;

// Farben
int bg = color(11, 12, 16);
int neonCyan = color(102, 252, 241);
int neonPink = color(255, 0, 127);
int neonGreen = color(57, 255, 20);
int darkGray = color(31, 40, 51);

// Spieldaten
int zeit = 0, fehler = 0, zustand = 1, strafSekunden = 3;
float gesamtZeit = 0;
int lastHardwareBtnState = 0;

String[] allTimeNames = {"---", "---", "---"}, todayNames = {"---", "---", "---"};
float[] allTimeTimes = {999.9, 999.9, 999.9}, todayTimes = {999.9, 999.9, 999.9};

boolean showSettings = false, showSavePrompt = false, showNameInput = false;
int newScoreIndexAll = -1, newScoreIndexToday = -1;
String playerName = ""; 

int lastBtnPressTime = 0; 

void setup() {
  size(1024, 768);
  cp5 = new ControlP5(this);
  
  cp5.addSlider("strafSekundenSlider")
     .setPosition(width/2-150, height/2)
     .setSize(300, 40)
     .setRange(1, 15)
     .setValue(3)
     .hide()
     .getCaptionLabel().hide(); 
  
  String portName = "COM4"; 
  
  try {
    myPort = new Serial(this, portName, 115200);
    myPort.bufferUntil('\n');
    myPort.write("DATE:" + year() + "-" + nf(month(), 2) + "-" + nf(day(), 2) + "\n");
    delay(100);
    myPort.write("GET_SCORES\n");
    println("ERFOLGREICH verbunden mit dem festen Port: " + portName);
  } catch (Exception e) {
    println("VERBINDUNGSFEHLER: Arduino an " + portName + " nicht erreichbar!");
  }
}

void draw() {
  background(bg);
  drawHUDGrid();
  drawClock(); 
  
  float sekunden = zeit / 1000.0;
  gesamtZeit = sekunden + (fehler * strafSekunden);

  drawTachometer(sekunden);
  drawStats(); 
  drawHighscores(); 
  drawButtons();

  if (showSettings) drawSettingsOverlay();
  if (showSavePrompt) drawSavePromptOverlay();
  else if (showNameInput) drawNameInputOverlay();
}

// --- VISUELLE KOMPONENTEN ---

void drawClock() { 
  fill(255); textSize(24); textAlign(LEFT, TOP); 
  // Uhrzeit verschoben, damit sie nicht auf den Linien liegt
  text(nf(hour(), 2) + ":" + nf(minute(), 2) + ":" + nf(second(), 2), 35, 35); 
}

void drawHUDGrid() {
  stroke(31, 40, 51, 100); strokeWeight(1);
  for (int i = 0; i < width; i += 40) line(i, 0, i, height);
  for (int i = 0; i < height; i += 40) line(0, i, width, i);
  stroke(neonCyan); strokeWeight(3); noFill();
  line(20, 20, 60, 20); line(20, 20, 20, 60);
  line(width-20, 20, width-60, 20); line(width-20, 20, width-20, 60);
}

void drawTachometer(float sek) {
  pushMatrix(); translate(width/2, 310); 
  noFill(); stroke(neonCyan, 150); strokeWeight(2); 
  ellipse(0, 0, 400, 400); 
  
  if (zustand == 2 || zustand == 3) { 
    stroke(neonCyan); strokeWeight(15); 
    arc(0, 0, 360, 360, PI, map(min(sek, 120.0), 0, 120.0, PI, TWO_PI+PI)); 
    strokeWeight(1);
  }
  
  fill(255); textAlign(CENTER, CENTER); 
  textSize(75); 
  text(nf(sek, 0, 2) + "s", 0, -30);
  
  textSize(35); 
  fill(neonPink); 
  text("FEHLER: " + fehler, 0, 50); 
  popMatrix();
}

void drawStats() {
  fill(255); textAlign(CENTER); textSize(24);
  
  // Berechnung der Formel-Teile
  float aktZeit = zeit / 1000.0;
  // Formatierung: Fehler x Strafzeit + Zeit =
  String formula = fehler + " x " + strafSekunden + "s + " + nf(aktZeit, 0, 2) + "s =";
  
  text(formula, width/2, 540); 
  
  textSize(50); // Gesamtzeit noch ein Stück größer für die Dominanz
  fill(neonGreen); 
  text(nf(gesamtZeit, 0, 2) + "s", width/2, 595);
}

void drawHighscores() {
  textAlign(LEFT); textSize(20); fill(neonCyan); text("ALL TIME", 50, 250);
  for(int i=0; i<3; i++) { fill(255); text((i+1)+". "+allTimeNames[i], 50, 300+(i*40)); text((allTimeTimes[i]==999.9?"---":nf(allTimeTimes[i],0,2)), 150, 300+(i*40)); }
  fill(neonPink); text("TODAY", width-250, 250);
  for(int i=0; i<3; i++) { fill(255); text((i+1)+". "+todayNames[i], width-250, 300+(i*40)); text((todayTimes[i]==999.9?"---":nf(todayTimes[i],0,2)), width-150, 300+(i*40)); }
}

void drawButtons() {
  drawCyberButton(width/2 - 100, 680, 200, 60, (zustand==2?"STOP":"START"), (zustand==2?neonPink:neonCyan));
  drawCyberButton(width-150, 30, 120, 40, "SETTINGS", neonCyan);
}

void drawCyberButton(float x, float y, float w, float h, String l, int c) {
  boolean hv = mouseX > x && mouseX < x+w && mouseY > y && mouseY < y+h;
  noFill(); stroke(hv?255:c); strokeWeight(2); rect(x, y, w, h, 5);
  fill(hv?c:255); textAlign(CENTER, CENTER); textSize(18); text(l, x+w/2, y+h/2-2);
}

// --- OVERLAYS ---

void drawSettingsOverlay() { 
  fill(0, 220); rect(0,0,width,height); 
  fill(darkGray); stroke(neonPink); strokeWeight(3);
  rect(width/2-250, height/2-150, 500, 340, 10); 
  fill(255); textAlign(CENTER); textSize(24);
  text("SYSTEM EINSTELLUNGEN", width/2, height/2 - 100);
  fill(neonPink); textSize(16);
  text("WARNUNG: ÄNDERUNG LÖSCHT ALLE REKORDE!", width/2, height/2 - 60);
  fill(255);
  text("Strafsekunden pro Fehler: " + int(cp5.getController("strafSekundenSlider").getValue()), width/2, height/2 - 20);
  drawCyberButton(width/2-110, height/2+80, 220, 40, "SPEICHERN & LÖSCHEN", neonPink); 
  drawCyberButton(width/2-110, height/2+130, 220, 40, "ZURÜCK", color(150)); 
}

void drawSavePromptOverlay() { 
  fill(0, 220); rect(0,0,width,height); 
  fill(darkGray); stroke(neonCyan); strokeWeight(3);
  rect(width/2-250, height/2-150, 500, 300, 10); 
  fill(neonCyan); textAlign(CENTER, CENTER); textSize(40);
  text("NEUER REKORD!", width/2, height/2 - 80);
  fill(255); textSize(20);
  text("War der Versuch gültig? Zeit speichern?", width/2, height/2 - 20);
  drawCyberButton(width/2-220, height/2+50, 200, 60, "JA (GÜLTIG)", neonGreen); 
  drawCyberButton(width/2+20, height/2+50, 200, 60, "NEIN (BETRUG)", neonPink); 
}

void drawNameInputOverlay() { 
  fill(0, 220); rect(0,0,width,height); 
  fill(neonCyan); textAlign(CENTER); textSize(40);
  text("NEUER REKORD!", width/2, height/2 - 120);
  fill(neonGreen); textSize(30);
  text("ZEIT: " + nf(gesamtZeit, 0, 2) + "s", width/2, height/2 - 70);
  fill(darkGray); stroke(neonCyan); strokeWeight(3);
  rect(width/2-150, height/2-30, 300, 80, 10); 
  fill(255); textSize(50); 
  text(playerName+(frameCount%60<30 && playerName.length()<3?"_":""), width/2, height/2+25); 
  textSize(20); fill(150);
  text("Tippe 3 Buchstaben/Zahlen und drücke ENTER", width/2, height/2 + 90);
}

// --- EVENTS ---

void mousePressed() {
  if (showSettings) { if (mouseX > width/2-110 && mouseX < width/2+110 && mouseY > height/2+80 && mouseY < height/2+120) { if(myPort!=null) myPort.write("NEWSTR:" + int(cp5.getController("strafSekundenSlider").getValue()) + "\n"); } showSettings = false; cp5.getController("strafSekundenSlider").hide(); return; }
  if (showSavePrompt) { if (mouseY > height/2+50 && mouseY < height/2+110) { if (mouseX > width/2-220 && mouseX < width/2-20) { showSavePrompt = false; playerName = ""; showNameInput = true; } else { showSavePrompt = false; } } return; }
  if (showNameInput) return; 
  if (mouseY > 670 && mouseY < 740 && mouseX > width/2 - 100 && mouseX < width/2 + 100) triggerBtn(); 
  if (mouseX > width-150 && mouseY < 70) { showSettings = true; cp5.getController("strafSekundenSlider").setValue(strafSekunden); cp5.getController("strafSekundenSlider").show(); }
}

void triggerBtn() { 
  if (myPort == null) return;
  if (millis() - lastBtnPressTime < 1000) return;
  lastBtnPressTime = millis();
  if (zustand != 2) myPort.write("START\n"); else myPort.write("STOP\n"); 
}

void keyPressed() {
  if (showNameInput) {
    if (key == BACKSPACE && playerName.length() > 0) playerName = playerName.substring(0, playerName.length()-1);
    else if (key == ENTER || key == RETURN) { 
      String fT = nf(gesamtZeit,0,2).replace(',','.'); 
      if (myPort != null) {
        if (newScoreIndexAll!=-1) myPort.write("SAVESCORE:ALL:"+newScoreIndexAll+":"+(playerName.length()==0?"---":playerName)+":"+fT+"\n"); 
        delay(50);
        if (newScoreIndexToday!=-1) myPort.write("SAVESCORE:TODAY:"+newScoreIndexToday+":"+(playerName.length()==0?"---":playerName)+":"+fT+"\n"); 
      }
      showNameInput = false; myPort.write("RESET\n"); 
    }
    else if (playerName.length() < 3 && ((key >= 'a' && key <= 'z') || (key >= 'A' && key <= 'Z') || (key >= '0' && key <= '9'))) playerName += (""+key).toUpperCase();
  }
}

void serialEvent(Serial p) {
  try {
    String in = trim(p.readString()); if (in == null) return;
    if (in.startsWith("SCORES;")) { 
      String[] s = split(in, ';'); if (s.length >= 13) { for(int i=0; i<3; i++) { allTimeNames[i]=s[1+(i*2)]; allTimeTimes[i]=float(s[2+(i*2)]); todayNames[i]=s[7+(i*2)]; todayTimes[i]=float(s[8+(i*2)]); } } 
    } else { 
      String[] l = split(in, ';'); 
      if (l.length == 5) { 
        zeit=int(l[0]); fehler=int(l[1]); int aZ=zustand; zustand=int(l[2]); strafSekunden=int(l[3]); 
        if (int(l[4])==1 && lastHardwareBtnState==0) { if (!showSavePrompt && !showNameInput && !showSettings) triggerBtn(); }
        lastHardwareBtnState=int(l[4]); 
        if (aZ==2 && zustand==3) checkHigh(); 
      } 
    }
  } catch (Exception e) {}
}

void checkHigh() {
  newScoreIndexAll = -1; newScoreIndexToday = -1;
  for(int i=0; i<3; i++) { if (gesamtZeit < allTimeTimes[i]) { newScoreIndexAll = i; break; } }
  for(int i=0; i<3; i++) { if (gesamtZeit < todayTimes[i]) { newScoreIndexToday = i; break; } }
  if (newScoreIndexAll != -1 || newScoreIndexToday != -1) showSavePrompt = true;
}

5. Die Profi-Variante (4 Zoll TFT Display)

Bei dieser Version verbaust du ein großes 4" TFT Farbdisplay direkt in deinem Gehäuse. Damit erschaffst du ein völlig eigenständiges Gerät, das keinen Computer für die Anzeige benötigt. Du kannst darauf Menüs, Highscores und Timer grafisch ansprechend darstellen.

Technisch ist dies die anspruchsvollste Variante. Du musst das Display über den SPI-Bus verkabeln, was viele Pins belegt. Zudem nutzt du spezielle Grafik-Libraries, um Texte und Animationen Pixel für Pixel zu programmieren. Das Ergebnis ist dafür aber ein professionelles, mobiles Spielsystem mit intuitiver Benutzerführung aber aufwendiger Verdrahtung.

Der Arduino Code für das heiße Draht Spiel

#include <SPI.h>
#include <ILI9486_SPI.h>
#include <Encoder.h>
#include <EEPROM.h>

ILI9486_SPI tft(10, 8, 9); 
Encoder meinEnc(2, 3);

const int pinMenu = 4;      
const int pinStartStop = 5; 
const int pinDraht = 6;     
const int pinSummer = 7;    

enum GameState { CONFIG, RESET, LAEUFT, GESTOPPT, TIMEOUT };
volatile GameState zustand = CONFIG;

bool configSummer = true;
int configStrafSek = 3;
volatile int configSperreMs = 500; 
int menuPunkt = 0; 

unsigned long bestEverMs;    
unsigned long sessionBestMs; 
const int EEPROM_ADDR = 0;   
const unsigned long MAX_ZEIT = 300000UL; 
const unsigned long RESET_WERT = 5999900UL; 

volatile int fehlerCounter = 0; 
unsigned long startMillis;
volatile unsigned long lastFehlerMillis = 0; 
unsigned long lastDisplayUpdate = 0; 
long altePos = -999;

unsigned long menuBtnPressTime = 0;
bool menuBtnWasPressed = false;
volatile bool startStopTriggered = false; 

#define GRUEN   0x07E0
#define ROT     0xF800
#define GELB    0xFFE0
#define WEISS   0xFFFF
#define SCHWARZ 0x0000

// --- INTERRUPT SERVICE ROUTINE ---
ISR(PCINT2_vect) {
  unsigned long now = millis();
  
  if (zustand == LAEUFT && digitalRead(pinDraht) == LOW) {
    if (now - lastFehlerMillis > (unsigned long)configSperreMs) {
      fehlerCounter++;
      lastFehlerMillis = now;
    }
  }

  static unsigned long lastBtnTime = 0;
  if (digitalRead(pinStartStop) == LOW) {
    if (now - lastBtnTime > 300) { 
      startStopTriggered = true;
      lastBtnTime = now;
    }
  }
}

void setup() {
  pinMode(pinMenu, INPUT_PULLUP);
  pinMode(pinStartStop, INPUT_PULLUP);
  pinMode(pinDraht, INPUT_PULLUP);
  pinMode(pinSummer, OUTPUT);
  
  cli();
  PCICR |= (1 << PCIE2);
  PCMSK2 |= (1 << PCINT22); // Pin 6
  PCMSK2 |= (1 << PCINT21); // Pin 5
  sei();

  EEPROM.get(EEPROM_ADDR, bestEverMs);
  if (bestEverMs == 0xFFFFFFFF) bestEverMs = RESET_WERT; 
  sessionBestMs = RESET_WERT; 

  tft.setSpiKludge(false);
  tft.init(); 
  tft.setRotation(3);
  tft.fillScreen(SCHWARZ);
  zeichneMenu();
}

void loop() {
  if (startStopTriggered) {
    handleStartButtonInterrupt();
    startStopTriggered = false;
  }

  if (zustand == LAEUFT) {
    if (millis() < lastFehlerMillis + (unsigned long)configSperreMs) {
      if (configSummer) digitalWrite(pinSummer, HIGH);
    } else {
      digitalWrite(pinSummer, LOW);
    }
  }

  handleMenuNavigation();
  
  if (zustand == CONFIG) {
    handleEncoderSettings();
  }

  if (zustand == LAEUFT) {
    unsigned long cur = millis() - startMillis;

    // UPDATE-RATE AUF 50ms VERBESSERT (für 0,2,4,6,8 Anzeige)
    if (millis() - lastDisplayUpdate > 50) { 
      unsigned long strafeMs = (unsigned long)fehlerCounter * (unsigned long)configStrafSek * 1000UL;
      unsigned long total = cur + strafeMs;
      
      updateFehlerAnzeige();
      updateTimer(cur, total);
      lastDisplayUpdate = millis();

      if (cur >= MAX_ZEIT) {
        zustand = TIMEOUT;
        digitalWrite(pinSummer, LOW);
        tft.setCursor(50, 160); tft.setTextSize(3); tft.setTextColor(ROT, SCHWARZ);
        tft.print("ZU LANGE GEBRAUCHT!");
      }
    }
  }
}

// --- LOGIK ---

void handleMenuNavigation() {
  bool currentMenuBtn = digitalRead(pinMenu);
  if (currentMenuBtn == LOW && !menuBtnWasPressed) {
    menuBtnPressTime = millis();
    menuBtnWasPressed = true;
  }
  if (currentMenuBtn == HIGH && menuBtnWasPressed) {
    unsigned long pressDuration = millis() - menuBtnPressTime;
    if (pressDuration > 1500) {
      if (zustand == CONFIG && menuPunkt == 3) {
        bestEverMs = RESET_WERT;
        EEPROM.put(EEPROM_ADDR, bestEverMs);
        zeichneMenu();
      }
    } 
    else if (pressDuration > 50) {
      if (zustand != CONFIG) { 
        zustand = CONFIG; 
        tft.fillScreen(SCHWARZ); 
      } else {
        menuPunkt = (menuPunkt + 1) % 4;
      }
      zeichneMenu();
    }
    menuBtnWasPressed = false;
  }
}

void handleStartButtonInterrupt() {
    if (zustand == GESTOPPT || zustand == TIMEOUT || zustand == CONFIG) {
      displayGameReset();
      zustand = RESET;
    } 
    else if (zustand == RESET) {
      fehlerCounter = 0;
      lastFehlerMillis = 0;
      startMillis = millis();
      zustand = LAEUFT;
    }
    else if (zustand == LAEUFT) {
      zustand = GESTOPPT;
      pruefeRekorde();
    }
}

void handleEncoderSettings() {
  long neuePos = meinEnc.read() / 4;
  if (neuePos != altePos) {
    int diff = neuePos - altePos;
    if (menuPunkt == 0) configSummer = !configSummer;
    else if (menuPunkt == 1) configStrafSek = constrain(configStrafSek + diff, 0, 15);
    else if (menuPunkt == 2) configSperreMs = constrain(configSperreMs + (diff * 50), 300, 1300);
    altePos = neuePos;
    zeichneMenu();
  }
}

void pruefeRekorde() {
  unsigned long cur = millis() - startMillis;
  unsigned long total = cur + ((unsigned long)fehlerCounter * configStrafSek * 1000UL);
  if (total < bestEverMs) {
    bestEverMs = total;
    EEPROM.put(EEPROM_ADDR, bestEverMs);
    tft.setCursor(140, 280); tft.setTextSize(2); tft.setTextColor(ROT, SCHWARZ);
    tft.print("!! NEUER REKORD !!");
  }
  if (total < sessionBestMs) sessionBestMs = total;
  zeichneObenRechts();
}

// --- GRAFIK ---

void zeichneMenu() {
  tft.setCursor(80, 20); tft.setTextColor(WEISS, SCHWARZ); tft.setTextSize(3);
  tft.print("EINSTELLUNGEN");
  tft.setTextSize(2);
  tft.setCursor(40, 80); tft.setTextColor(menuPunkt == 0 ? GELB : WEISS, SCHWARZ);
  tft.print("1. Summer: "); tft.print(configSummer ? "AN  " : "AUS "); 
  tft.setCursor(40, 115); tft.setTextColor(menuPunkt == 1 ? GELB : WEISS, SCHWARZ);
  tft.print("2. Strafe: +"); tft.print(configStrafSek); tft.print(" Sek  "); 
  tft.setCursor(40, 150); tft.setTextColor(menuPunkt == 2 ? GELB : WEISS, SCHWARZ);
  tft.print("3. Sperre: "); tft.print(configSperreMs); tft.print(" ms   "); 
  tft.setCursor(40, 185); tft.setTextColor(menuPunkt == 3 ? GELB : WEISS, SCHWARZ);
  tft.print("4. Bestzeit: "); 
  if (bestEverMs >= RESET_WERT) tft.print("99:99.0"); else printTimeShort(bestEverMs);
  if (menuPunkt == 3) {
    tft.setCursor(40, 210); tft.setTextSize(1); tft.setTextColor(ROT, SCHWARZ);
    tft.print("(Menu-Taste HALTEN zum LOESCHEN)");
    tft.setTextSize(2);
  } else {
    tft.fillRect(40, 210, 300, 15, SCHWARZ);
  }
  tft.setCursor(40, 260); tft.setTextColor(GRUEN, SCHWARZ);
  tft.print("Start druecken zum RESETTEN ");
}

void displayGameReset() {
  if (zustand == CONFIG) tft.fillScreen(SCHWARZ);
  else {
    tft.fillRect(0, 275, 480, 45, SCHWARZ); 
    tft.fillRect(0, 140, 480, 120, SCHWARZ); 
  }
  fehlerCounter = 0; lastFehlerMillis = 0;
  zeichneObenRechts();
  updateFehlerAnzeige();
  updateTimer(0, 0); 
}

void zeichneObenRechts() {
  tft.setTextSize(2);
  tft.setCursor(260, 10); tft.setTextColor(ROT, SCHWARZ);  tft.print("Best: ");
  if (bestEverMs >= RESET_WERT) tft.print("99:99.0"); else printTimeShort(bestEverMs);
  tft.setCursor(260, 35); tft.setTextColor(WEISS, SCHWARZ); tft.print("Sess: ");
  if (sessionBestMs >= RESET_WERT) tft.print("99:99.0"); else printTimeShort(sessionBestMs);
}

void updateFehlerAnzeige() {
  tft.setCursor(10, 10); tft.setTextColor(ROT, SCHWARZ); tft.setTextSize(3);
  tft.print("Fehler: "); tft.print(fehlerCounter); tft.print("  "); 
}

void updateTimer(unsigned long cur, unsigned long total) {
  tft.setTextSize(3);
  tft.setCursor(30, 90); 
  tft.setTextColor(WEISS, SCHWARZ); 
  tft.print("Zeit:"); 
  printTimeLong(cur); 
  tft.print(" + ");
  tft.print(fehlerCounter * configStrafSek); 
  tft.print("s =  "); 

  tft.setCursor(60, 160); 
  tft.setTextSize(8);
  tft.setTextColor(GELB, SCHWARZ);  
  printTimeLong(total);
}

// ANGEPASST: ZEIGT JETZT NUR GERADE ZEHNTELSEKUNDEN (0,2,4,6,8)
void printTimeLong(unsigned long ms) {
  unsigned long m = ms / 60000UL; 
  unsigned long s = (ms % 60000UL) / 1000UL; 
  int t = (ms % 1000UL) / 100UL;
  
  t = (t / 2) * 2; // Glättung auf gerade Zahlen

  if(m < 10) tft.print("0"); tft.print(m); tft.print(":");
  if(s < 10) tft.print("0"); tft.print(s); tft.print("."); tft.print(t);
}

void printTimeShort(unsigned long ms) {
  unsigned long m = ms / 60000UL; 
  unsigned long s = (ms % 60000UL) / 1000UL; 
  int t = (ms % 1000UL) / 100UL;
  
  t = (t / 2) * 2; // Glättung auf gerade Zahlen

  if(m < 10) tft.print("0"); tft.print(m); tft.print(":");
  if(s < 10) tft.print("0"); tft.print(s); tft.print("."); tft.print(t);
  tft.print(" ");
}

Kontakt

Ronnie

schwäbischer tüftler und bastler, kraftsportler, neurodivers, 45 Jahre, 1 Frau, 5 Kinder und 1003 Ideen.